Errores personalizados en ASP clásico

Código ASP clásico

Versión de Microsoft Internet Information Services Server (IIS) 5.0 introduce la posibilidad de crear páginas de error de páginas Active Server (ASP) personalizadas mediante la incorporación de un nuevo método para el objeto de servidor ASP integrado denominado Server.GetLastError() que devuelve un nuevo objeto ASPError.

Cuando se produce un error al compilar o ejecutar una página ASP, IIS genera un error 500; 100 y ejecuta un método Server.Transfer() para pasar el control a la página de error personalizado definido actualmente. (De forma predeterminada esta página es /iishelp/common/500-100.asp.)

Cuando el control se pasa a la página de error personalizado, puede utilizarse el método Server.GetLastError() para obtener información detallada sobre el error producido. El método Server.GetLastError() devuelve un objeto ASPError que tiene las propiedades que aparecen en la tabla siguiente. (Esta tabla también puede encontrarse en la documentación en pantalla de IIS 5.0.)

Propiedad Descripción
ASPCode Devuelve un código de error generado por IIS.
Número Devuelve el código de error COM estándar.
Origen Indica si el origen del error era interno de ASP, el lenguaje de secuencias de comandos o un objeto.
Archivo Indica el nombre del archivo .asp que se estaba procesando al producirse el error.
Línea Indica la línea del archivo .asp que generó el error.
Descripción Devuelve una breve descripción del error.
ASPDescription Devuelve una descripción más detallada del error si es un error relacionado con ASP.

Los siguientes pasos recorrerá en la configuración de una página de error personalizada de ASP.

1. Guarde el siguiente código ASP en la carpeta Scripts como "My500.asp" (sin las comillas):

  <%
  Option Explicit
  On Error Resume Next
  Response.Clear
  Dim objError
  Set objError = Server.GetLastError()
%>


<h2 align="center">ASP 500 Error</h2>

<p align="center">An error occurred processing the page you requested.<br>
Please see the details below for more information.</p>

<div align="center"><center>

<table>
<% If Len(CStr(objError.ASPCode)) > 0 Then %>
  <tr>
    <th nowrap align="left" valign="top">IIS Error Number</th>
    <td align="left" valign="top"><%=objError.ASPCode%></td>
  </tr>
<% End If %>
<% If Len(CStr(objError.Number)) > 0 Then %>
  <tr>
    <th nowrap align="left" valign="top">COM Error Number</th>
    <td align="left" valign="top"><%=objError.Number%>
    <%=" (0x" & Hex(objError.Number) & ")"%></td>
  </tr>
<% End If %>
<% If Len(CStr(objError.Source)) > 0 Then %>
  <tr>
    <th nowrap align="left" valign="top">Error Source</th>
    <td align="left" valign="top"><%=objError.Source%></td>
  </tr>
<% End If %>
<% If Len(CStr(objError.File)) > 0 Then %>
  <tr>
    <th nowrap align="left" valign="top">File Name</th>
    <td align="left" valign="top"><%=objError.File%></td>
  </tr>
<% End If %>
<% If Len(CStr(objError.Line)) > 0 Then %>
  <tr>
    <th nowrap align="left" valign="top">Line Number</th>
    <td align="left" valign="top"><%=objError.Line%></td>
  </tr>
<% End If %>
<% If Len(CStr(objError.Description)) > 0 Then %>
  <tr>
    <th nowrap align="left" valign="top">Brief Description</th>
    <td align="left" valign="top"><%=objError.Description%></td>
  </tr>
<% End If %>
<% If Len(CStr(objError.ASPDescription)) > 0 Then %>
  <tr>
    <th nowrap align="left" valign="top">Full Description</th>
    <td align="left" valign="top"><%=objError.ASPDescription%></td>
  </tr>
<% End If %>
</table>

</center></div>

2. Establecer la página de error personalizada de ASP:


    1. Abra el Administrador de servicios de Internet en MMC.
    2. Expanda el sitio Web predeterminado.
    3. Haga clic en la carpeta Scripts y seleccione Propiedades.
    4. Haga clic en la ficha Errores personalizados ..
    5. Desplácese hacia abajo y resaltar el error HTTP 500; 100 y haga clic en Editar propiedades.
    6. Asegúrese de que el Tipo de mensaje está establecido en la dirección URL.
    7. Cambiar la dirección URL para "/ scripts/my500.asp" (sin las comillas).
    8. Haga clic en Aceptar para regresar a la consola MMC.

tags: asp clasico, proveedores asp, servidor para asp, hosting para asp, pagian web asp, como personalizar una pagina web, ejemplos servidor web

En esta sección encontrarás una mezcla de códigos recopilados de fuentes públicas de Internet y otros creados por ASP TEAM. Compartimos recursos útiles de buena fe para formar una base de conocimiento en el desarrollo de aplicaciones en ASP Clásico.